Kokkuvõte
Mitme maksusulgude põhjal kogu tulumaksu arvutamiseks võite kasutada näites näidatud struktureeritud VLOOKUP-i ja määrade tabelit. G5 valem on:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
kus "inc" (G4) ja "rate" (B5: D11) nimetatakse vahemikeks ja veerg D on abiveerg, mis arvutab igas sulgudes kogunenud kogumaksu.
Taust ja kontekst
USA maksusüsteem on "progressiivne", mis tähendab, et suurema maksustatava sissetulekuga inimesed maksavad kõrgemat föderaalset maksumäära. Määrasid hinnatakse sulgudes, mis on määratletud ülemise ja alumise künnisega. Kindlasse sulgudesse langeva tulu summa maksustatakse selle sulgude vastava määraga. Maksustatava tulu suurenedes maksustatakse tulu rohkemate maksusulgude kaudu. Paljud maksumaksjad maksavad seetõttu mitut erinevat määra.
Näidatud näites on maksusulgud ja -määrad Ameerika Ühendriikide üksikutele viilijatele 2019. maksuaastaks. Allolevas tabelis on esitatud käsitsi arvutused 50 000 dollari maksustatava tulu kohta:
| Sulg | Arvutus | Maks |
|---|---|---|
| 10% | (9 700–0 USD) x 10% | 970,00 dollarit |
| 12% | (39 475–9 700 dollarit) x 12% | 3573,00 dollarit |
| 22% | (50 000 - 39 475 dollarit) x 22% | 2315,50 dollarit |
| 24% | NA | 0,00 dollarit |
| 32% | NA | 0,00 dollarit |
| 35% | NA | 0,00 dollarit |
| 37% | NA | 0,00 dollarit |
Kogumaks on seega 6858,50 dollarit. (näidatud näites kuvatakse kui 6859).
Seadistamise märkused
1. See valem sõltub funktsioonist VLOOKUP "ligikaudses sobitusrežiimis". Ligikaudses sobitusrežiimis olles skannib VLOOKUP tabeli otsinguväärtusi (mis tuleb sortida kasvavas järjekorras), kuni leitakse suurem väärtus. Siis see "astub tagasi" ja tagastab eelmise rea väärtuse. Täpse vaste korral tagastab VLOOKUP vastava rea tulemused.
2. Selleks, et VLOOKUP saaks kätte tegelikud kumulatiivsed maksusummad, lisati need tabelisse veeru D abistaja veeruna. D6-s valem, mis on kopeeritud, on järgmine:
=((B6-B5)*C5)+D5
Igas reas rakendab see valem ülaltoodud rea määra selles sulgudes olevale tulule.
3. Loetavuse huvides on määratletud järgmised nimevahemikud: "inc" (G4) ja "rate" (B5: D11).
Selgitus
G5-s on esimene VLOOKUP konfigureeritud hankima kumulatiivne maks marginaalse määraga nende sisenditega:
- Otsingu väärtus on "inc" (G4)
- Otsingu tabel on "hinnad" (B5: D11)
- Veeru number on 3, kumulatiivne maks
- Vaste tüüp on 1 = ligikaudne vaste
VLOOKUP(inc,rates,3,1) // returns 4,543
Maksustatava tuluga 50 000 dollarit sobib VLOOKUP ligikaudses mängurežiimis 39 475 ja tagastab 4543, kogu maks kuni 39 475 dollarit.
Teine VLOOKUP arvutab ülejäänud maksustatava tulu:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
arvutatakse järgmiselt:
(50 000-39 475) = 10 525
Lõpuks saab kolmas VLOOKUP (ülemise) marginaalse maksumäära:
VLOOKUP(inc,rates,2,1) // returns 22%
See korrutatakse eelmises etapis arvutatud sissetulekuga. Kogu valem on lahendatud järgmiselt:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Piir- ja efektiivsed määrad
Lahter G6 sisaldab ülemist piirmäära, mis arvutatakse VLOOKUP-iga:
=VLOOKUP(inc,rates,2,1) // returns 22%
G7 tegelik maksumäär on kogu maks jagatud maksustatava tuluga:
=G5/inc // returns 13.7%
Märkus. Jooksin selle valemiga Jeff Lenningu blogis Exceli ülikoolis. See on suurepärane näide sellest, kuidas VLOOKUP-i saab kasutada ligikaudses sobitusrežiimis, ja ka seda, kuidas VLOOKUP-i saab mitu korda kasutada samas valemis.
